对平台函数【AccHelp_AutoID 自增序号函数 】的重写

时　间:2013-04-19 14:15:42
作　者:Aaron   ID：20267  城市：闵行
摘　要:AccHelp_AutoID 自增序号函数 
功能： AccHelp_AutoID函数可用于自动编号，例如： B00001 B00002 B00003
 
但是在很多时候，编码的前缀是变化的，例如前缀代表分类信息。这个时候自增段，就要根据编码来重新计数，而不是根据整个表的记录条数来计数的。
所以对系统的函数进行了重写：
正　文:

AccHelp_AutoID 自增序号函数

    功能： AccHelp_AutoID函数可用于自动编号，例如： B00001 B00002 B00003

但是在很多时候，编码的前缀是变化的，例如前缀代表分类信息。这个时候自增段，就要根据编码来重新计数，而不是根据整个表的记录条数来计数的。

所以对系统的函数进行了重写：

加入到一个模块中，声明为Public类型函数即可。

'////////////////////////////////////////////////////////////////////////
'///////////
'//函数名：AutoPrefixCode
'//编写者：Aaron Dong
'//参考资料：
'//功能：自动生成带前缀的编号
'//输入参数：Prefix:编号前缀;字符型
'                   NumberLength:自增数字段位数;数字型
'                   TableName: 表名称; 字符型
'                   FieldName:字段名称; 字符型
'                   BasedOnPrefix:递增段是否基于前缀; 布尔型
'//输出参数：自动生成的编号：字符类型
'//备注：
'///////////
'////////////////////////////////////////////////////////////////////////
Public Function AutoPrefixCode(PreFix As String, NumberLength As Integer, TableName As String, FieldName As String, BasedOnPrefix As Boolean) As String
    Dim strMax As String
    Dim strFormat As String
    Dim i As Integer
    strMax = FieldName
    '//如果编码的计数基于前缀
    If BasedOnPrefix Then
        For i = 1 To NumberLength
            strFormat = strFormat & "0"
        Next
        AutoPrefixCode = Nz(DMax(strMax, TableName, FieldName & " LIKE '" & PreFix & "*'"), "")
        If Len(AutoPrefixCode) = 0 Then

            AutoPrefixCode = PreFix & Format("1", strFormat)
        Else
            AutoPrefixCode = PreFix & Format(CLng(Replace(AutoPrefixCode, PreFix, "")) + 1, strFormat)
        End If
    '//如果编码的计数不基于前缀
    Else
        AutoPrefixCode = acchelp_autoid(PreFix, NumberLength, TableName, FieldName)
    End If
End Function