怎样用代码最大化、最小化ACCESS的主窗口

时　间:2018-10-18 09:07:15
作　者:刺客   ID：69836  城市：宁波
摘　要:怎样用代码最大化、最小化ACCESS的主窗口
正　文:

通过一函数已定义的常量 fSetAccessWindow 实现。 
该函数能用来完全隐藏 Access 窗口并将你自己的窗体显示在桌面上。注意，必须已经打开一个弹出式窗体才能使用 SW_HIDE 参数调用 fSetAccessWindow 函数实现。 

注   意:

如果你隐藏了 Access 主窗口，要确定你有良好的出错处理。因为主窗口隐藏后，一旦引发错误，并出错提示窗口上点击了“结束”按钮，这样不会使 Access 主窗口可见，并退出你自己的窗体。推荐你在你的错误处理程序中使用 SW_SHOWNORMAL 参数调用 fSetAccessWindow 函数来显示 Access 主窗口。 

如果由于别的原因，Access 主窗口不能显示，那么你将只能从任务栏中关闭你的 mdb，在 Win 9x 中使用 Control-Alt-Delete 来结束任务，在 Win NT 、2000 或 XP 中，可以右键单击任务栏选择任务管理器来选择该 mdb 结束任务。 
代   码:

'************ 代码开始 **********
Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3

Private Declare Function apiShowWindow Lib "user32" _
    Alias "ShowWindow" (ByVal hwnd As Long, _
    ByVal nCmdShow As Long) As Long

Function fSetAccessWindow(nCmdShow As Long)
' 使用举例
' 最大化 Access 窗口
'　　　 fSetAccessWindow(SW_SHOWMAXIMIZED)
' 最小化 Access 窗口
'　　　 fSetAccessWindow(SW_SHOWMINIMIZED)
' 隐藏 Access 窗口
'　　　 fSetAccessWindow(SW_HIDE)
' 正常显示 Access 窗口
'　　　 fSetAccessWindow(SW_SHOWNORMAL)
'
    Dim loX As Long
    Dim loFORM As Form
On Error Resume Next
    Set loFORM = Screen.ActiveForm
    If Err <> 0 Then ' 没有活动窗体 no ActiveFORM
        If nCmdShow = SW_HIDE Then
            MsgBox "除非屏幕上有一个窗口，否则不能隐藏 Access 主窗口!" _
                & vbCr & vbCr _
                & "Cannot hide Access unless " _
                & "a FORM is on screen"
        Else
            loX = apiShowWindow(hWndAccessApp, nCmdShow)
            Err.Clear
        End If
    Else
        If nCmdShow = SW_SHOWMINIMIZED And loFORM.Modal = True Then
            MsgBox "不能由屏幕上的 " & (loFORM.Caption + " ") & "窗体最小化 Access 主窗口!" _
                & vbCr & vbCr _
                & "Cannot minimize Access with " _
                & (loFORM.Caption + " ") _
                & "FORM on screen"
        ElseIf nCmdShow = SW_HIDE And loFORM.PopUp <> True Then
            MsgBox "不能由屏幕上的 " & (loFORM.Caption + " ") & "窗体隐藏 Access 主窗口!" _
                & vbCr & vbCr _
                & "Cannot hide Access with " _
                & (loFORM.Caption + " ") _
                & "FORM on screen"
        Else
            loX = apiShowWindow(hWndAccessApp, nCmdShow)
        End If
    End If
    fSetAccessWindow = (loX <> 0)
End Function

'************ 代码结束 **********
 

看过先辈发表的关于隐藏Access窗体的技术文章，在使用过程中发现会使窗体的自动居中属性改变，或使子窗体的滚动条消失，经过不断试验，终于克服以上现象，与大家分享以下代码：
Private Declare Function ShowWindow Lib "user32" _
  (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Private Sub Form_Load()
    ShowWindow Me.Application.hWndAccessApp, 2
End Sub


Access软件网官方交流QQ群 (群号:54525238) 　　　　　　Access源码网店