Access快速开发平台批量添加权限控制代码

时　间:2017-11-01 10:07:04
作　者:红尘如烟   ID：10768  城市：成都
摘　要:Access快速开发平台批量添加权限控制代码
正　文:

      今天遇到一位网友用Access快速开发平台开发的软件里面，所有权限控制的代码都丢失的问题，如果手动一个一个加代码的话太麻烦了，整理了一个程序批量添加，只需要把这个函数的代码放到模块里面，然后执行一下即可。
就可以批量为所有窗体添加权限控制代码了。
不需要再一个个的去手动加了。

注   意:
其他网友如果你的Access快速开发平台里面没有出现权限控制代码丢失的情况，请不要用这个方法。
执行后自动生成的代码是在Load事件里面的。如下图:

'批量添加权限控制代码如下:
Sub AddPermissionCodes()
    Dim obj As AccessObject
    Dim lngCount As Long: lngCount = CurrentProject.AllForms.Count
    Dim lngI As Long
    For Each obj In CurrentProject.AllForms
        lngI = lngI + 1
        If obj.Name Like "frm*" Then
            If Not (obj.Name Like "*_Edit" or obj.Name Like "*_List") Then
                DoCmd.OpenForm obj.Name, acDesign, , , , acHidden
                               
                Dim frm As Form: Set frm = Forms(obj.Name)
                Dim strFormKey As String: strFormKey = ""
                strFormKey = Mid(frm.Name, 4)
                Dim strVBA As String: strVBA = ""
                Dim ctl As Control
                For Each ctl In frm.Controls
                    If TypeOf ctl Is CommandButton Then
                        Select Case ctl.Name
                        Case "btnClose", "btnRefresh"
                        Case Else
                            Dim strCtlKey As String: strCtlKey = ""
                            strCtlKey = frm.Controls(ctl.Name & "_Label").Caption
                            strVBA = strVBA & "    EnableButton Me." & ctl.Name & ", HasPermission(""" & strFormKey & """, """ & strCtlKey & """)" & vbCrLf
                        End Select
                    End If
                Next
'                Debug.Print strVBA
                Dim mdl As Module: Set mdl = frm.Module
                mdl.InsertLines mdl.ProcBodyLine("Form_Load", vbext_pk_Proc) + 1, strVBA
                DoCmd.Close acForm, obj.Name, acSaveYes
                Debug.Print "已处理 " & lngI & "/" & lngCount, obj.Name
            End If
        End If
    Next
End Sub